ANNOALLVISIBLE

[alf]

ANNOALLVISIBLE - jest taka zmienna która powoduje wyświetlenie w bloku wymiarowania. Tzn gdy zmienna jest 0 to się nie wyświetla wymiarowanie a gdy 1, to tak.

Na layoutach (starych) domyślnie jest u mnie ona 0. Każdorazowo na każdym layoucie, gdzie domyślnie mam 0 muszę ustawić to na 1 Czy da się globalnie ustawić, dla całego rysunku, a nie dla każdego layoutu osobno by była "1"?

vernum = "25.00_2024.09.04(#15253-247870170b3)_x64" (read only)

Edytowane Wtorek o 17:12 przez alf

[kojacek]

Tych parę nawiasów wraz z treścią umieszczoną pomiędzi nimi, zmienia wartosc tej zmiennej dla kazdego layoutu (bez modelu) na przeciwną. Potrzeba CADPL-Pack'a załadowanego wcześniej.

; -------------------------------------------------------------------------------------------- ;
; Polecenie C:L-ANNO zmienia zmienna ANNOALLVISIBLE dla kazdego layoutu na wartosc przeciwna   ;
; by kojacek 2024                                                                              ;
; -------------------------------------------------------------------------------------------- ;
(defun C:L-ANNO (/ %i :a)
  (defun :a (x)(getpropertyvalue x "AnnoAllVisible"))
  (foreach % (layoutlist)
    (setq %i (vlax-vla-object->ename
               (vla-item (cd:ACX_Layouts) %)
             )
    )
    (setpropertyvalue %i "AnnoAllVisible"
      (abs (1- (:a %i)))
    )
    (princ
      (strcat
        "\nDla układu " %
        " zmieniono ustawienie ANNOALLVISIBLE na "
        (itoa (:a %i))
      )
    )
  )
  (princ)
)
; -------------------------------------------------------------------------------------------- ;

W AC działa, nie wiem jak w jemu podobnych.

kojacek

Edytowane Wtorek o 18:59 przez kojacek

[alf]

oo. dzięki

po teście w zw2025, począkowe ustawienie 0:

Command: ANNOALLVISIBLE
Enter ANNOALLVISIBLE's new value  <0>: *Cancel*
Command: L-ANNO
extraExplode:*error*: undefined function - CD:ACX_LAYOUTS

[kojacek]

Cytat

Potrzeba CADPL-Pack'a załadowanego wcześniej.

 

[alf]

mam taką wersję (2019):

po załadowaniu jej taki wynik;

Command: L-ANNO
extraExplode:*error*: undefined function - GETPROPERTYVALUE

 

[kojacek]

Cytat

W AC działa, nie wiem jak w jemu podobnych.

GETPROPERTYVALUE, SETPROPERTYVALUE oraz DUMPALLPROPERTIES są w AC pewnie już z 10 lat. Zatem z rzekomą zgodnością różnie bywa.

[alf]

no czymś różnić się musi.. i dlatego pewnie ma swoje komendy

[kojacek]

Zatem... Załaduj poniższych parę nieci innych nawiasów. Polecenie L-ANNO2 . Pack musi być. Przetestuj proszę.

; -------------------------------------------------------------------------------------------- ;
; Polecenie C:L-ANNO2 zmienia zmienna ANNOALLVISIBLE dla kazdego layoutu na wartosc przeciwna  ;
; operujac na XDATA                                                                            ;
; by kojacek 2024                                                                              ;
; -------------------------------------------------------------------------------------------- ;
(defun C:L-ANNO2 (/ %n %i %l)
  (setq %n "AcadAnnoAV")
  (foreach % (layoutlist)
    (setq %i (vlax-vla-object->ename
               (vla-item (cd:ACX_Layouts) %)
             )
    )
    (setq %l
      (length 
        (if
          (not 
            (cd:XDT_GetXData %i %n)
          )
          (cd:XDT_PutXData %i %n '((1070 . 1)))
          (cd:XDT_RemoveXData %i %n)
        )
      )
    )
    (princ
      (strcat
        "\nDla układu " %
        " zmieniono ustawienie ANNOALLVISIBLE na "
        (if (< 10 %l) "1" "0")
      )
    )
  )
  (princ)
)
; -------------------------------------------------------------------------------------------- ;

 

[alf]

chodzi,

ale z powrotem nie wraca do ustawienia 0 (tj z 1 na 0). Co prawda mi potrzebne tylko przejście na 1, ale dla porządku przekazuję tę informację, bo może ktoś chciał by w drugą stronę

Command: L-ANNO2
Dla układu OD-4.1_PW_Urz oczyszczl[A3] zmieniono ustawienie ANNOALLVISIBLE na 0
Dla układu OD-4.4_PT_Urz oczyszczl[A3] zmieniono ustawienie ANNOALLVISIBLE na 0
Command: ANNOALLVISIBLE
Enter ANNOALLVISIBLE's new value  <1>: *Cancel*

 

Tak ogólnie to wielkie dzięki za pomoc

 

[kojacek]

W AC działa w dwie strony. Bez zarzutu. Jak przełącznik radiowy. Albo 0 albo 1. 

[alf]

tu, w zw, jak raz przekręcisz gałkę i klops, jak zepsute radio Erewań.

Ale dla mnie to dobrze, bo w pliku miałam kilka layoutów ustawienia na 1 a sporą część na 0 i wszystkie mi ustawił na 1.

 

[pawmal]

Tak na marginesie, bardzo łatwo sprawdzić jak jest ustawiona widoczność tych elementów opisowych.

[alf]

Merci!